# Copyright © Advanced Micro Devices, Inc., or its affiliates.
#
# Redistribution and use in source and binary forms, with or without modification,
# are permitted provided that the following conditions are met:
# 1. Redistributions of source code must retain the above copyright notice, this
#    list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright notice,
#    this list of conditions and the following disclaimer in the documentation
#    and/or other materials provided with the distribution.
# 3. Neither the name of the copyright holder nor the names of its contributors
#    may be used to endorse or promote products derived from this software without
#    specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
# ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (
# INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
# OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
# NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE,
# EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

# Basic examples
set(EXAMPLE_SOURCES
    simple_gemm_f32.c
    multi_instance_gemm_f32.c
    simple_gemm_bf16.c
    simple_gemm_s8.c
    simple_gemm_with_bias.c
    simple_gemm_with_relu.c
    matrix_reorder.c
    batch_gemm.c
    quantization.c
    post_ops_combinations.c
    eltwise_ops.c
    version.c
)

find_package(OpenMP REQUIRED COMPONENTS C CXX)

# Create an executable for each example source file
foreach(source ${EXAMPLE_SOURCES})
    # Extract the filename without extension
    get_filename_component(example_name ${source} NAME_WE)

    # Add executable
    add_executable(${example_name} ${source})

    # Add include directories
    target_include_directories(${example_name}
        PRIVATE
            ${PROJECT_SOURCE_DIR}/include
    )

    # Choose library target based on static linking preference
    if(DLP_EXAMPLES_LINK_STATIC)
        set(DLP_LIBRARY_TARGET ${PROJECT_NAME}_static)
        message(STATUS "Linking example ${example_name} with static AOCL-DLP library (whole-archive automatic)")
    else()
        set(DLP_LIBRARY_TARGET ${PROJECT_NAME})
        message(STATUS "Linking example ${example_name} with shared AOCL-DLP library")
    endif()

    # Link with the main library
    # Note: For static library, whole-archive is automatically applied via INTERFACE_LINK_OPTIONS
    target_link_libraries(${example_name}
        PRIVATE
            ${DLP_LIBRARY_TARGET}
    )

    # Link with OpenMP if available
    if(OpenMP_C_FOUND)
        target_link_libraries(${example_name} PRIVATE OpenMP::OpenMP_C)
    endif()
    if(OpenMP_CXX_FOUND)
        target_link_libraries(${example_name} PRIVATE OpenMP::OpenMP_CXX)
    endif()
    if(OpenMP_C_FOUND OR OpenMP_CXX_FOUND)
        target_compile_definitions(${example_name} PRIVATE DLP_EXAMPLE_ENABLE_OPENMP)
    endif()

    # Link with math library on Unix/Linux only
    target_link_libraries(${example_name}
        PRIVATE
            $<$<BOOL:${UNIX}>:m>
    )

    # Apply centralized compiler flags
    dlp_set_global_compile_flags(${example_name})

    # Install the example
    install(TARGETS ${example_name}
        RUNTIME DESTINATION examples/classic
    )
endforeach()

# Copy example source files to the installation directory
install(FILES ${EXAMPLE_SOURCES}
    DESTINATION examples/classic/src
)

# Install a readme file with building instructions
configure_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/README.md.in
    ${CMAKE_CURRENT_BINARY_DIR}/README.md
    @ONLY
)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/README.md
    DESTINATION examples/classic
)
